問：
您好，腳本專家！如何運行腳本取消隱藏文件夾中的所有文件？
-- GA
答：
您好，GA。您知道我們中的一位腳本專家在年少時和鄰居家的其他小孩花費無數的時間玩各種捉迷藏。事實上，這位腳本專家仍清晰地記得躺在淺溝中，讓其他組的人從他身上走過，卻不知道他就在那兒。（這種方法如此奏效，以致于他正認真考慮在自己的辦公室挖一條淺溝，這樣有人找他的時候就可以躲在淺溝里了。）
回到那些日子，您不會想要一種能自動取消隱藏一切的腳本；這種腳本可能很有用，但卻沒什么樂趣。但作為系統管理員，您大概并不愿意與文件玩捉迷藏。您或許樂意接受能自動取消隱藏文件夾中所有文件的腳本，也就是類似如下的腳本：
復制代碼 代碼如下:
strComputer = "."
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set FileList = objWMIService.ExecQuery _
("ASSOCIATORS OF {Win32_Directory.Name='c:\Scripts'} Where " _
& "ResultClass = CIM_DataFile")
Set objFSO = CreateObject("Scripting.FileSystemObject")
For Each objFile In FileList
Set objFile = objFSO.GetFile(objFile.Name)
If objFile.Attributes AND 2 Then
objFile.Attributes = objFile.Attributes XOR 2
End If
Next
此腳本有些不同尋常，因為我們同時使用了 WMI 和 FileSystemObject。（當然，這聽起來很危險，其實不然：畢竟，我們是經過專門訓練的專業人員。）首先連接到本地計算機的 WMI 服務（我們馬上就會談到這一點），然后使用以下查詢檢索 C:\Scripts 文件夾下所有文件的集合（也就是 CIM_DataFile 類的所有實例）：
Set FileList = objWMIService.ExecQuery _
("ASSOCIATORS OF {Win32_Directory.Name='c:\Scripts'} Where " _
& "ResultClass = CIM_DataFile")
我們使用 WMI 檢索文件的集合，因為使用它十分快捷，并且在多數情況下可以使用同一腳本向外從遠程計算機檢索文件的集合。然而遺憾的是，WMI 無法用于取消隱藏文件；CIM_DataFile 類確實包括一個名為 Hidden 的屬性，但它是只讀屬性。這就是我們必須同時使用 WMI 和 FileSystemObject 的原因：我們使用 WMI 獲取文件的集合，然后使用 FileSystemObject 取消隱藏這些文件。
令人沮喪的是，這也意味著此腳本必須在本地計算機上運行；因為與 WMI 不同，FileSystemObject 無法遠程工作。真是差勁。
不管怎樣，獲得文件集合后，我們創建一個 FileSystemObject 實例然后建立一個 For Each 循環以遍歷此組文件。在 For Each 循環內，使用下行代碼綁定到每個文件：
Set objFile = objFSO.GetFile(objFile.Name)
正如您所見，我們只是調用了 GetFile 方法，為其傳遞 Name 屬性的值（使用 WMI 獲得）。Name 屬性相當于文件路徑；因此文件“名”至少在 WMI 中類似于 C:\Scripts\My_file.txt。
綁定到給定文件后，檢查文件是否隱藏；隱藏或未隱藏正好是文件屬性的一部分。使用下行代碼檢查是否打開了隱藏屬性的“開關”。如果開關打開、文件隱藏，則此語句為 True。如果開關關閉、文件未隱藏，此語句為 False：
If objFile.Attributes AND 2 Then
注意。文件屬性是作為 bitmask 屬性存儲的。在本專欄中，我們不詳細說明 bitmask 屬性的詳細內容，但您可以在 Microsoft Windows 2000 腳本指南 中找到 bitmask 的詳細解釋和使用方法。
為什么要關心文件是否已隱藏？取消對隱藏文件的隱藏最簡單的方法是將開關由開轉為關，事實上，下行代碼就起到這一作用：
objFile.Attributes = objFile.Attributes XOR 2
但是，XOR 運算符并非特別聰明：它只是將開關由一種狀態轉為另一狀態。如果開關為開，就將其關閉；如果開關為關，就將其打開。這就是我們檢查文件當前狀態的原因。如果文件被隱藏，則要使用 XOR 將開關由打開轉為關閉。但是，如果文件未被隱藏，應該怎么辦呢？這種情況下，不需要轉換開關；這樣做會隱藏文件。（因為 XOR 會將開關由關轉為開。）因此在開始轉換開關前，應檢查每個文件的值。
運行此腳本 – 找到你們了，都出來吧！– 之前隱藏的所有文件都會重新出現。然后輪到您藏起來，看看這些文件能否找到您。
