在Web應用程序中，當一個用戶訪問該應用時，Session類型的變量可以供這個用戶在該Web應用的所有頁面中共享數據；如果另一個用戶也同時訪問該Web應用，他也擁有自己的Session變量，但兩個用戶之間無法通過Session變量共享信息，而Application類型的變量則可以實現站點多個用戶之間在所有頁面中共享信息。可以理解Session是局部變量，而Application則為全局變量。
在同一虛擬目錄及其子目錄下的所有 .asp 文件構成了 ASP 應用程序。我們非但可以使用 Application 對象，在給定的應用程序的所有用戶之間共享信息，并在服務器運行期間持久的保存數據。而且，Application 對象還有控制訪問應用層數據的方法和可用于在應用程序啟動和停止時觸發過程的事件。
一、Application("name")=Value
正如Session("name")=value一樣，Application對象也沒有內置的屬性。當然用戶可以自定義屬性，該屬性也可稱為集合。
一旦分配了Application對象的屬性，它就會持久地存在，直到關閉WEB服務器服務使得 Application 停止。由于存儲在 Application 對象中的數值可以被應用程序的所有用戶讀取，所以 Application 對象的屬性特別適合在應用程序的用戶之間傳遞信息。
|
<%
Application("MyName") = "cnbruce"
%>
|
二、Application.Lock
Lock方法是禁止其他用戶修改Application對象的屬性，以確保在同一時刻僅有一個客戶可修改和存取 Application 變量。如果用戶沒有明確調用 Unlock 方法，則服務器將會在 .asp 文件結束或超時后即解除對 Application 對象的鎖定。最簡單的就是進行頁面記數的例子了。
1，num.asp
|
<%
Application.Lock
Application("NumVisits") = Application("NumVisits") + 1
Application.Unlock
%>
你是本頁的第<%=Application("NumVisits")%>位訪問者
|
當然，若如果你需要記數的初始值那就該寫個判斷了。
|
<%
if Application("NumVisits")<9999 then
Application("NumVisits")=10000
end if
Application.Lock
Application("NumVisits") = Application("NumVisits") + 1
Application.Unlock
%>
你是本頁的第<%=Application("NumVisits")%>位訪問者
|
上面的程序，你會發現每刷新一次，都會記數累加，如按IP值訪問來記數的話，則建立一個Session
2，vnum.asp
|
<%
if session("visitnum")="" then
Application.Lock
Application("NumVisits") = Application("NumVisits") + 1
Application.Unlock
session("visitnum")="visited"
end if
%>
你是本頁的第<%=Application("NumVisits")%>位訪問者
|
三、Application.Unlock
與Lock方法相反，Unlock方法是允許其他用戶修改 Application 對象的屬性?？梢钥闯鲈谏厦娴睦又?，Unlock方法解除對象的鎖定，使得下一個客戶端能夠增加 NumVisits 的值。
當然需要注意的是：記數要確保服務器不被重啟，因為所以的訪問是數值是建立在頁面之上的，并未進行保存成文件或保存到數據庫這樣的處理。
一般當服務器重新啟動就會觸發Application的事件了。
四、Application_OnEnd
Application_OnEnd 事件在應用程序退出時于 Session_OnEnd 事件之后發生，當然Application_OnEnd 事件的處理過程也必須寫在 Global.asa 文件之中。
比如上面的程序中，若服務器關機必然會觸發Application_OnEnd事件，那么該事件就可以進行數據保存的工作，已使得下次數據的續沿。
當然Application_OnEnd 事件在應用程序退出時于Session_OnEnd 事件之后發生
|
<SCRIPT LANGUAGE="VBScript" RUNAT="Server">
.............
Sub Application_OnEnd
.............
End Sub
.............
</SCRIPT>
|
五、Application_OnStart
Application_OnStart 事件在首次創建新的會話( 即 Session_OnStart 事件 )之前發生。當WEB服務器啟動并允許對應用程序所包含的文件進行請求時就觸發Application_OnStart事件。
|
<SCRIPT LANGUAGE=ScriptLanguage RUNAT=Server>
.............
Sub Application_OnStart
.............
End Sub
.............
</SCRIPT>
|
所以現在可以將Global.asa內部的代碼可以想象
|
<SCRIPT LANGUAGE="VBScript" RUNAT="Server">
Sub Application_OnStart
.....................
End Sub
Sub Session_OnStart
.....................
End Sub
Sub Session_OnEnd
.....................
End Sub
Sub Application_OnEnd
.....................
End Sub
</SCRIPT>
|
具體Global.asa是怎么一回事？且聽下回分解?。海?/span>
5大對象基本掌握了，來個例題練習下
|
<%@ LANGUAGE = VBScript %>
<% Option Explicit %>
<Html>
<title>猜數字游戲</title>
<body>
<%
'設置頁面不使用緩存
Response.Expires = 0
%>
<%
dim GuessNum
on error resume next
GuessNum=Request("Number")
if GuessNum="" then GuessNum="0" End if
GuessNum=Clng(GuessNum)
Session("Count")=Session("Count") + 1
if Session("Count") < 10 and GuessNum <> session("Number") then
%>
<form action="guessNumber.asp">
<input type="text" name="Number">
<input type="submit" value="提交">
</form>
<hr>
<%
end if
if GuessNum<0 or guessNum>100 then
Response.write "請輸入1~100之間的整數"
elseif GuessNum=0 then
session("Count") = 0
Randomize
session("Number") = Int(rnd * 100 + 1)
Response.write "請輸入1~100之間的整數"
elseif GuessNum > session("Number") then
response.write "你猜的太大了"
elseif GuessNum < session("Number") then
response.write "你猜的太小了"
elseif GuessNum = session("Number") then
response.write "祝賀你,猜對了"
end if
Response.write "<br>共猜了" & Session("Count") & "次"
if Session("Count")=10 then
Response.write "答案是" & Session("Number")
end if
%>
<a href="guessnumber.asp?Number=0">重新猜</a>
</body>
</html>
|
Test URL: http://www.cnbruce.com/test/aspcode/guessnumber.asp
